当前位置:asp编程网>技术教程>Asp教程>  正文

jmail发送邮件函数

2007-11-14 17:22:52   来源:    作者:佚名   浏览量:5030   收藏
<%
'smtp为邮件服务器名
'user为smtp邮件服务器上的邮件地址
'pwd为smtp邮件服务器上的邮件的密码
'sendto为要发送的邮件地址
'from发件人名
'subject为主题
'body为邮件内容
function sendmail(smtp,sendto,from,user,pwd,subject,body)
Set jmail = Server.CreateObject("JMAIL.Message") '建立发送邮件的对象 
jmail.silent = true '屏蔽例外错误,返回FALSE跟TRUE两值j 
jmail.logging = true '启用邮件日志 
'加上如下语句,否则还有可能出现乱码的可能性: 
jmail.Charset = "GB2312" '邮件的文字编码为国标 
jmail.ContentTransferEncoding = "base64"   
jmail.Encoding = "base64"   
jmail.ISOEncodeHeaders = false

'jmail.ContentType = "text/html" '邮件的格式为HTML格式 -- 有此句则发送附件时为乱码
jmail.AddRecipient sendto '邮件收件人的地址 
jmail.From = from '发件人的E-MAIL地址 
jmail.MailServerUserName = user '登录邮件服务器所需的用户名 
jmail.MailServerPassword = pwd '登录邮件服务器所需的密码 
jmail.Subject = subject '邮件的标题 
jmail.Body = body '邮件的内容 
'jmail.AddAttachment Server.MapPath("login.gif")'附件--不能有此句:jmail.ContentType = "text/html"
'Jmail.AddAttachment Server.MapPath("b.rar")      '否则附件会变成乱码
jmail.Priority = 3 '邮件的紧急程序,1 为最快,5 为最慢, 3 为默认值 
if jmail.send(smtp)=false then'执行邮件发送(通过邮件服务器地址) 
    sendmail=0
else
    sendmail=1
end if
jmail.Close
end Function

'举例
smtp1="smtp.163.com"
user1="你的邮箱@163.com"
pwd1="邮箱的密码"
sendto1="要发送人的邮箱"
from1="你的邮箱@163.com" '要和user中的内容一样
subject1="邮件的主题"
body1="邮件内容"
t=sendmail(smtp1,sendto1,from1,user1,pwd1,subject1,body1)
if t=1 then
  response.write "发送成功"
else
  response.write "发送失败"
end if
%>
(鼠标移到代码上去,在代码的顶部会出现四个图标,第一个是查看源代码,第二个是复制代码,第三个是打印代码,第四个是帮助)

 



关于我们-广告合作-联系我们-积分规则-网站地图

Copyright(C)2013-2017版权所属asp编程网